私が以前作ったやつとりあえず載せときます。
レイアウトも設定してからコマンド打って書く枚数など設定すると印刷される(はず)です。
少し前に作ったので、精査していませんのでご了承ください。
(変なところ教えていただいたら幸いです。)
他の書き込み見ても変だと思ったので、そもそも論から
1.(defun c:～ から初めて、コマンド定義づけから始めてください。
前後の流れが分からず、プログラムが半端なところ過ぎて指摘しづらいです。
2.変数名は日本語ではなく英語(アルファベット)にしてください。
たぶんコマンドライン上に出るコメントと変数名が逆です。
変数名も混ざっていてわかりづらいです。
3.repeat処理
Countaが増えてはいるようですが、ループ内でcountaによって値が変わるものがありません。
この場合は、意味がないです。
(entlast)を使っていますが、これは最後に作成したオブジェクトを取得するだけで、
位置などを取得するわけではありません。
全体的にちぐはぐになってしまっていて、
アドバイスもしづらいです。
最初から書き直してみて、
関数名を調べて返す値と取得しなければいけない値を明確にすると
分かりやすくなると思います。
自ら解決できるよう応援しております。
以下、LISP
------------------------------
(defun c:rowplot
( / Old_Os Old_Cm layObj pltObj acadDoc genten kiten syuten i
kyori xkyori ykyori
yokoichi tateichi)
;初期設定の保存
(setq Old_Os (getvar "OSMODE"));オブジェクトスナップの保存
(setq Old_Cm (getvar "CMDECHO"));エコーモードの保存
;
;エラー処理(初期設定の戻し)
(defun *error* (msg)
(setvar "OSMODE" Old_Os);オブジェクトスナップの戻し
(setvar "CMDECHO" Old_Cm);エコーモードの戻し
(princ))
;オブジェクトスナップ、エコーモードを無効化
(setvar "OSMODE" 0)
(setvar "CMDECHO" 0)
;vl関数の読み込み
(vl-load-com)
;現在の図面のオブジェクトを読み込み
(setq acadDoc (vla-get-ActiveDocument (vlax-get-Acad-object)))
(setq layObj (vla-get-ActiveLayout acadDoc))
(setq pltObj (vla-get-plot acadDoc))
;窓印刷の座標を取得
(vla-GetWindowToPlot layObj 'genten 'syuten)
(setq genten (vlax-safearray->list genten)
syuten (vlax-safearray->list syuten)
)
(setq kyori (list (setq xkyori (- (car syuten) (car genten)))
(setq ykyori (- (cadr syuten) (cadr genten)))
)
)
;;印刷の尺度を取得
(Vla-getcustomscale layObj 'Numerator 'Denominator)
(setq syaku (/ Numerator Denominator))
;ダイアログボックスの呼び出し&値を取得
;houkou:左下なら「1」左上なら「-1」
;tate:縦の図面枚数
;yoko:横の図面枚数
;maisu:枚数の合計
(setq yoko 0 maisu 0)
(rowplot_SetVar)
(setq tate (atoi tate)
yoko (atoi yoko)
maisu (atoi maisu)
)
(if (= maisu 0)
(setq maisu (* tate yoko))
)
;原点座標をユーザーに指定
(setvar "OSMODE" 1);オブジェクトスナップモードを端点に指定
;オブジェクトスナップを無効化
(setvar "OSMODE" 0)
;縦位置、横位置の初期設定
(setq tateichi 0)
(setq yokoichi 0)
(setq i 0)
;ここからループ処理
(while (< i maisu)
;;縦位置が縦の同じの場合、1に戻して、横位置を増やす。
;;違う場合、縦位置を+1する
(if (= tateichi tate)
(progn
(setq tateichi 1)
(setq yokoichi (+ yokoichi 1))
)
(progn
(setq tateichi (+ tateichi 1))
)
)
;;紙面の起点位置を設定
(setq kiten
(list (+ (car genten) (* xkyori yokoichi) (* yoko-yohaku yokoichi))
(+ (cadr genten) (* ykyori (- tateichi 1)) (* tate-yohaku (- tateichi 1)))
)
)
;;紙面の終点位置を設定
(setq syuten
(list (+ (car kiten) xkyori)
(+ (cadr kiten) ykyori)
)
)
(if (= (getvar 'CTAB) "Model")
(command-s "-plot"
"y" ;詳細な印刷環境設定? [はい(Y)/いいえ(N)] <いいえ>:
"" ;レイアウト名を入力 または [一覧(?)] <モデル>:enter,そのまま
"" ;出力デバイス名を入力 または [一覧(?)] <DocuWorks Printer>:
"" ;用紙サイズを入力 または [一覧(?)] <A3 (297x420mm)>:
"m" ;用紙単位を入力 [インチ(I)/ミリメートル(M)] <ミリメートル>:
"" ;図面の方向を入力 [縦(P)/横(L)] <横>:
"" ;上下を反転して印刷しますか? [はい(Y)/いいえ(N)] <いいえ>:
"w" ;印刷領域を入力 [表示画面(D)/オブジェクト範囲(E)/図面範囲(L)/ビュー(V)/窓(W)] <窓>:
kiten ;窓の左下コーナーを入力 <0.000000,0.000000>:
syuten ;窓の右上コーナーを入力 <841.000000,594.000000>:
syaku ;印刷尺度を入力 (印刷 ミリメートル=作図単位) または [フィット(F)] <1=2>:
"" ;印刷オフセット(x,y)を入力 または [中心(C)] <中心>:
"" ;印刷スタイルを使用して印刷しますか? [はい(Y)/いいえ(N)] <はい>:
"" ;印刷スタイル テーブル名を入力 または [一覧(?)] ( . = なし) <黄色→黒.ctb>:
"" ;線の太さを使用して印刷しますか? [はい(Y)/いいえ(N)] <はい>:
"" ;シェーディング印刷の設定を入力 [表示どおり(A)/旧式ワイヤフレーム(W)/旧式隠線処理(H)/表示スタイル(V)/レンダリング(R)] <旧式ワイヤフレーム>:
"N" ;印刷をファイルへ書き出しますか [はい(Y)/いいえ(N)] <N>:
"N" ;ページ設定の変更を保存しますか [はい(Y)/いいえ(N)]? <N>
"y" ;印刷を続けますか [はい(Y)/いいえ(N)] <Y>:
)
(command-s "-plot"
"y" ;詳細な印刷環境設定? [はい(Y)/いいえ(N)] <いいえ>:
"" ;レイアウト名を入力 または [一覧(?)] <モデル>:enter,そのまま
"" ;出力デバイス名を入力 または [一覧(?)] <DocuWorks Printer>:
"" ;用紙サイズを入力 または [一覧(?)] <A3 (297x420mm)>:
"m" ;用紙単位を入力 [インチ(I)/ミリメートル(M)] <ミリメートル>:
"" ;図面の方向を入力 [縦(P)/横(L)] <横>:
"" ;上下を反転して印刷しますか? [はい(Y)/いいえ(N)] <いいえ>:
"w" ;印刷領域を入力 [表示画面(D)/オブジェクト範囲(E)/図面範囲(L)/ビュー(V)/窓(W)] <窓>:
kiten ;窓の左下コーナーを入力 <0.000000,0.000000>:
syuten ;窓の右上コーナーを入力 <841.000000,594.000000>:
syaku ;印刷尺度を入力 (印刷 ミリメートル=作図単位) または [フィット(F)] <1=2>:
"" ;印刷オフセット(x,y)を入力 または [中心(C)] <中心>:
"" ;印刷スタイルを使用して印刷しますか? [はい(Y)/いいえ(N)] <はい>:
"" ;印刷スタイル テーブル名を入力 または [一覧(?)] ( . = なし) <黄色→黒.ctb>:
"" ;線の太さを使用して印刷しますか? [はい(Y)/いいえ(N)] <はい>:
"" ;印刷尺度を使用して線の太さを尺度変更しますか? [はい(Y)/いいえ(N)] <はい>:
"" ;ペーパー空間を最初に印刷しますか? [はい(Y)/いいえ(N)] <いいえ>:
"" ;ペーパー空間のオブジェクトを隠線処理しますか? [はい(Y)/いいえ(N)] <いいえ>:
"N" ;印刷をファイルへ書き出しますか [はい(Y)/いいえ(N)] <N>:
"N" ;ページ設定の変更を保存しますか [はい(Y)/いいえ(N)]? <N>
"y" ;印刷を続けますか [はい(Y)/いいえ(N)] <Y>:
)
)
(setq i (1+ i))
;ループ処理の終了
)
;オブジェクトスナップ、エコーモードの戻し
(setvar "OSMODE" Old_Os)
(setvar "CMDECHO" Old_Cm)
;変数をnilにしておく。
(setq tate nil);縦の図面枚数
(setq yoko nil);横の図面枚数
(setq maisu nil);枚数の合計
(princ)
)
;---------------------------------------------
;ダイアログボックスから値を取得するサブルーチン
;---------------------------------------------
(defun rowplot_GetVar ()
(setq tate (get_tile "tate"));縦の図面枚数
(setq yoko (get_tile "yoko"));横の図面枚数
(setq maisu (get_tile "maisu"));枚数の合計
(setq tate-yohaku (atoi (get_tile "tate-yohaku")));縦の余白
(setq yoko-yohaku (atoi (get_tile "yoko-yohaku")));横の余白
)
;---------------------------------------------
;ダイアログボックスを作成して表示するサブルーチン
;---------------------------------------------
;(dcl_write "rowplot.dcl")
(defun rowplot_SetVar (/ file-open file-name str dcl-id)
(setq file-open (open (setq file-name (vl-filename-mktemp "" "" ".dcl")) "w"))
(foreach str
'("// rowplot.dcl for use in A1Layout.lsp //"
"rowplot_setting :dialog"
"{ label = \"連続印刷の設定\";"
"//--------------------------------------------------------"
" : row {"
" : column {//colmun1_START"
" children_fixed_height = 3;"
" :boxed_column {label = \"図面枚数\";"
" alignment = left;"
" :edit_box{"
" label = \"縦の枚数\";"
" edit_width = 5;"
" key = \"tate\"; }"
" :edit_box{"
" label = \"横の枚数\";"
" edit_width = 5;"
" key = \"yoko\"; }"
" :edit_box{"
" label = \"合計枚数\";"
" edit_width = 5;"
" key = \"maisu\"; }"
" }//boxed_column"
" :boxed_column {label = \"図面間の余白(実測値)\";"
" :edit_box{"
" label = \"縦の余白\";"
" edit_width = 5;"
" alignment = left;"
" key = \"tate-yohaku\"; }"
" :edit_box{"
" label = \"横の余白\";"
" edit_width = 5;"
" alignment = left;"
" key = \"yoko-yohaku\"; }"
" }//boxed_column"
" }//colmun1 "
" }//row "
"ok_cancel;"
"}"
)
(write-line str file-open)
);end make dcl
(close file-open)
(setq ctblst (vl-directory-files (getenv "PrinterStyleSheetDir") "*.ctb"))
(new_dialog "rowplot_setting" (setq dcl-id (load_dialog file-name)))
(set_tile "StPt" "LeDw" )
(action_tile "accept" "(rowplot_GetVar)(done_dialog 1)")
(action_tile "cancel" "(done_dialog 0)")
(setq Act (start_dialog))
(unload_dialog dcl-id)
(cond
((= Act 0)(princ "キャンセルキーを押しました"))
((= Act 1)(princ "OKを押しました"))
);cond
(vl-file-delete file-name)
(princ)
)
(princ "\n印刷設定などを行ってレイアウトの適用をしてから\n「rowplot」と入力すると連続で印刷を行います。")
